超經典！Excel中SUMIF函數10大高級用法

▌1、單欄位單條件求和

計算「楊過」總銷售額，公式：SUMIF(D2:D16,"楊過",E2:E16)

單欄位單條件求和

▌2、單欄位多條件求和

計算「楊過」和「楊逍」兩個人的總銷售額，共有兩種方法。

方法1：藉助SUMIF進行數學運算，楊過總銷售額+楊逍總銷售額。

公式：SUMIF(D2:D16,"楊過",E2:E16)+SUMIF(D2:D16,"楊逍",E2:E16)

方法1

方法2：藉助SUM和SUMIF實現單欄位多條件求和，SUM（楊過銷售額，楊逍銷售額）。

公式：SUM(SUMIF(D2:D16,{"楊過","楊逍"},E2:E16))

方法2

注意：SUMIF(D2:D16,{"楊過","楊逍"},E2:E16)是一個數組公式，指代的結果是{楊過銷售額,楊逍銷售額}，再用SUM公式求和，即可得到楊過與楊逍的總銷售額。

▌3、包含日期的單欄位多條件求和

計算8月20日至9月20日總銷售額，有兩種方法。

方法1：藉助SUM和SUMIF實現單欄位多條件求和，SUM（8月20日以後的銷售額，9月20日之前的銷售額）。

公式：SUM(SUMIF(A2:A16,{">=2016/8/20",">2016/9/20"},E2:E16)*{1,-1})。

相當於=SUMIF(A2:A16,">=2016/8/20",E2:E16)-SUMIF(A2:A16,">2016/9/20",E2:E16)，即8月20日至9月20日的銷售額=8月20日以上的銷售額-9月20日以後的銷售額。

方法1

方法2：藉助SUMIFS實現多條件求和，同時滿足8月20日以後和9月20日之前兩個條件的銷售額。

公式：SUMIFS(E2:E16,A2:A16,">=2016-8-20",A2:A16,"<=2016-9-20")

sumifs多條件求和

注意：SUMIFS函數是 Excel 2007及以後版本的新增函數，不能在 Excel 2003 中使用，但是可以使用SUMIF函數的普通公式來實現（如方法1）。

▌4、模糊條件求和

SUMIF語法中criteria參數中支持使用通配符(包括問號「?」和星號「*」)。關於通配符的介紹，請移步姐姐之前的文章：花3分鐘學好Excel通配符，節省3小時。

計算姓「楊」銷售員的總銷售額，公式：SUMIF(D2:D16,"楊*",E2:E16)。

模糊條件求和

▌5、多列區域求和

計算各月借方和貸方合計。

公式：SUMIF($B$2:$I$2,J$2,$B3:$I3)。

多列區域求和

注意：選中單元格，按F4，則單元格絕對引用，再按一次F4，則單元格相對引用鎖定行，再按一次F4，則單元格相對引用鎖定列，盡量避免一個個輸入「$」符號。

▌6、錯列求和

楊過的銷售總額。

公式：SUMIF(A1:C16,"楊過",B1:D16)。

錯列求和

注意：查找條件為銷售員「楊過」，條件區域為銷售員，求和區域比查找區域往右偏移一列，意思是統計銷售員右一列的數據，即各銷售員的銷售額。

▌7、錯行求和

計算銷售員總銷售額。

方法1公式：SUMIF(A1:A8,A2,B1:B8)，與基本用法一致。

公式2公式：SUMIF(B1:B8,"*",B2:B9)。

錯行求和

注意：查找條件為「*」，說明查找的是0個或多個字元，求和區域比查找區域往下偏移一行，意思是統計0個或多個字元下一行單元格的數據，即為各銷售員的銷售額。

▌8、查找引用

一說到查找引用，可能很多小夥伴會說，查找引用不是應該是VLOOKUP函數或者INDEX+MATCH函數嗎？關SUMIF函數什麼事兒呢？它只是一個求和函數而已。

的確，在絕大多數時候，查找引用不需要SUMIF，但是當求和區域符合條件的數值只有一個時，求和得到的結果就是數值本身，因此可以藉助SUMIF來實現查找引用。

現需匹配鄭州、長沙、武漢、合肥4個省會城市的銷售量、單價、銷售額、利潤額。

公式：SUMIF($A$2:$A$16,$G2,B$2:E$16)。

查找引用

注意：當原始數據表中有兩個及以上鄭州、長沙等省會城市名稱時，銷售量、單價、銷售額、利潤額等結果均為求和以後的結果。

▌9、排除錯誤值求和

計算全國銷售總量。由於銷售量中有不同類型的錯誤值，所以不能用SUM直接求和，可以使用SUMIF函數實現排除錯誤值求和。

公式：SUMIF(B2:B16,"<9e307",B2:B16)

排除錯誤值求和

注意：9e07是科學記數法表示的9*10^307，是接近Excel允許鍵入的最大數值9.99999999999999E+307的一個數。

在這裡表示對小於最大值9e07的數據進行求和，也就是對「數值」單元格進行求和。使用9e07不是規定，不是原則，是大家約定俗成的用法。

當然結合案例，也可以使用「<500」或者「<1000」等任意大於最大值253的值。

替換9e07結果仍然保持不變

▌10、跨表條件求和

在Oh,NO！你竟以為Excel求和函數只有SUM？？一文中姐姐介紹過跨表求和，較為基礎的求和方式，今天再給大家介紹如何在跨表的基礎上還能滿足一定的條件進行求和。

原始數據

如果只有1月這一個表，則合計公式為：SUMIF('1月'!$A:$A,$A2,'1月'!$B:$B)

單表匯總

實現跨表條件求和需要藉助INDIRECT函數（對文本描述的單元格引用，也就是說INDIRECT的括弧里的參數是一個字元串（文本）描述的文本形式，INDIRECT取得這個引用。）

最終公式為：

=SUMPRODUCT(SUMIF(INDIRECT(ROW($1:$3)&"月!$A:$A"),$A2,INDIRECT(ROW($1:$3)&"月!$B:$B")))

跨表求和公式分析

好啦，SUMIF函數的10大經典用法就介紹完了，教程寫的好辛苦啊！寫得這麼詳細，有些知識百度都出來，希望能夠對大家有用，更重要的是為大家提供一種解決問題的思路。

註：歡迎大家關注小編的微信公眾號「土木智庫」，裡面有小編整理的建築行業的眾多資料，有一建、二建、造價、消防視頻和課件，歡迎大家的加入。